見つかりません

検索条件をクリア

Almightタグリファレンス / Version 4.0 beta

タグは [ ] で囲んで記述する方法と、行頭に@を置いて記述する方法があります。

[ ]で囲む方法は、 [タグ名 属性名=属性値] の形で記述します。 行頭に@を置く方法は、 @タグ名 属性名=属性値 の形で記述します。

後者の記法では閉じカッコが不要になりますが、同じ行に複数のタグを書くことができません。 それ以外に違いはないので、場合によって使い分けが可能です。

また、行頭のタブは全て無視されるためインデントとして利用出来ます。

全タグ共通

cond属性

式を評価する

属性名 必須 デフォルト 説明
cond NO boolean trueならタグを実行、falseならタグを実行しない

全てのタグで使える共通属性です。

cond属性の式を評価してtrueの時だけ実行されます。

// ゲーム変数 f.test に true を代入する
[eval exp="f.test = true"]

// ゲーム変数 f.test には true が代入されているので
[ch text="ここが表示される" cond="f.test == true"]
[ch text="ここは表示されない" cond="f.test == false"]

システム操作

cancelskip

スキップモードを解除

このタグを通過したときにスキップモードになっていれば解除します

cancelauto

オートモードを解除

このタグを通過したときにオートモードになっていれば解除します

clearsysvar

システム変数を全てリセット

システム変数(sf)を全てリセットします

[eval exp="sf={}"] と等価です。

close

ゲームウィンドウを閉じる

属性名 必須 デフォルト 説明
ask NO boolean true trueなら終了確認ダイアログを表示、falseなら確認せずに終了

確認ダイアログを表示し、OKされるとゲーム画面を閉じます。 キャンセルされた場合は処理が続行されるため、 [close] の後は [jump] で先頭に戻ったり、 [s] などでシナリオを停止したりしてください

ブラウザで実行中の場合、ウィンドウやタブが閉じられないときはページが白紙になり、確実にゲームが終了されるようにします。

// 以下の場合は確認ダイアログが表示されます。
[close]
[close ask=true]

// 以下の場合は即時にウィンドウが閉じます
[close ask=false]

注意点として、終了確認ダイアログの表示には「almight.UI.dialog」メソッドを利用しているため、 プラグインで「blue-ui.html」などのUIプラグインを読み込んでないとエラーになります。(通常は気にする必要はありません)

hidemessage

メッセージレイヤーを非表示

メッセージレイヤーを非表示にします。

非表示状態の時にゲーム画面をクリックすると、再度表示されます。

loadjs

JavaScriptの実行

属性名 必須 説明
src YES string JavaScriptファイルへのパス

JavaScriptファイルを実行します。

通常はこのタグでJavaScriptの実行をするのではなく「almight.config.js」ファイルで、 ゲーム起動時にJavaScriptを実行します。

quake

画面を揺らす

属性名 必須 デフォルト 説明
time YES number 揺れ時間をミリ秒で指定
hmax NO number 10 横揺れの最大ピクセル数
vmax NO number 10 縦揺れの最大ピクセル数
interval NO number 30 揺れを発生させるインターバルをミリ秒で指定(20以下は指定しないようにしてください)
layer NO "base", number, "message", "message0", "message1"… 全てのレイヤー "base"は背景レイヤー、0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤー 、省略すると全てのレイヤーが対象となります

パラメータには0を指定することが可能で、縦揺れ・横揺れの表現ができます。

このタグは揺れの終了を待たずにシナリオを進行します。待つ場合は [wq] を直後に記述してください。 また、その際にレイヤーを指定した場合は [wq] にも同様のレイヤーを指定して下さい。

// 全てのレイヤーを一秒間横揺れさせます
[quake time=1000 hmax=10 vmax=0]
[wq]

// 前景レイヤー1だけを一秒間縦揺れさせます
[quake layer=1 time=1000 hmax=0 vmax=10]
[wq layer=1]

wq

画面揺らしの終了を待つ

属性名 必須 デフォルト 説明
canskip NO boolean false trueならスキップ可能、falseならスキップさせない
layer NO "base", number, "message", "message0", "message1"… 全てのレイヤー "base"は背景レイヤー、0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤー 、省略すると全てのレイヤーが対象となります

画面揺らしの終了を待ちます

// 画面揺らし効果をクリックで終了できます
[quake time=1000]
[wq canskip=true]

//以下場合なら、クリックしても画面揺らし効果を終了しません
[quake time=1000]
[wq canskip=false]

[quake time=1000]
[wq]

stopquake

画面揺らしの実行を中止

属性名 必須 デフォルト 説明
layer NO "base", number, "message", "message0", "message1"… 全てのレイヤー "base"は背景レイヤー、0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤー 、省略すると全てのレイヤーが対象となります

[quake]で画面を揺らしている最中の場合、画面揺らしの実行を停止します。

// 以下のように書くとテキスト後のpタグでクリックした後に画面揺らし効果が終了します。
[quake time=5000]
テキストです[p]
[stopquake]

// 以下のようにquakeタグにレイヤーを指定した場合は、stopquakeタグにも同様のレイヤーを指定してください
[quake layer=0 time=5000]
テキストです[p]
[stopquake layer=0]

s

シナリオ処理を停止

シナリオの進行処理を停止します。

選択肢を表示した時など、ユーザーのアクションを待つときに利用出来ます。

title

ゲームウィンドウのタイトル名を設定

属性名 必須 説明
name YES string ゲームウィンドウに表示するタイトル

ブラウザやPC向けビューワーでゲームを実行中、タイトルバーに表示されるタイトル名を設定出来ます。 configのtitleで指定するものと同一です。

// 以下のように書くとタイトルバーが「リファレンスです」に変更されます
[title name="リファレンスです"]

モバイル向けビューワーでは、タイトルバーが無いため影響がありません。

wait

指定された秒数だけ待つ

属性名 必須 デフォルト 説明
time YES number 待ち時間をミリ秒で指定
canskip NO boolean true trueならスキップ可能、falseならスキップさせない

指定された秒数だけ、シナリオの進行処理を停止します。

// 以下のように書くと三秒間進行処理が停止し、その間クリックしても進行しません
[wait time=3000 canskip=false]

// 以下の場合は、クリックで進行処理が再開されます
[wait time=3000 canskip=true]
[wait time=3000]

waitclick

クリックを待つ

このタグで待っているときはクリック待ち記号が表示されません。 また、スキップ状態が解除され、オートモードでも進みません。

togglesidebar

サイドバーを表示

サイドバーを表示します。

enablesave

セーブ機能を有効にする

サイドバーのセーブ機能を使用可能な状態にします。 セーブは本編シナリオのみでオンにするようにし、タイトル画面等、不要な場面では [disablesave] で使用しないようにして下さい。選択肢表示状態ではセーブすることができます。

disablesave

セーブ機能を無効にする

サイドバーのセーブ機能を使用不能な状態にします。

enableload

ロード機能を有効にする

サイドバーのロード機能を使用可能な状態にします。

disableload

ロード機能を無効にする

サイドバーのロード機能を使用不能な状態にします。

showcontroller

サイドバーにコントローラーを表示

サイドバーに本編シナリオで使用する「クイックセーブ」「クイックロード」「スキップ」「オートモード」「ヒストリー表示」の機能を表示します。 タイトル画面など、不必要な場面では [hidecontroller] で使用しないようにして下さい。

hidecontroller

サイドバーのコントローラーを非表示

サイドバーに表示されている「クイックセーブ」「クイックロード」「スキップ」「オートモード」「ヒストリー表示」の機能を非表示にします。

showcgmodewindow

CGモードを表示

サイドバーで「CGモード」を選択すると表示されるCGモードのウィンドウを、このタグで表示することができます。 ただし、「almight.config.js」で「cgmode.html」をプラグインとして読み込んでいる場合のみ利用可能です。

このタグでCGモードウィンドウを表示している間もシナリオは進行するので、進行処理を止めておきたい場合は [waitclick] 等を使って下さい。

hidecgmodewindow

CGモードを非表示

CGモードウィンドウを非表示にします。 ただし、「almight.config.js」で「cgmode.html」をプラグインとして読み込んでいる場合のみ利用可能です。

showhistorywindow

メッセージ履歴を表示

サイドバーで「ヒストリー表示」を選択すると表示されるメッセージ履歴のウィンドウを、このタグで表示することができます。 ただし、「almight.config.js」で「history.html」をプラグインとして読み込んでいる場合のみ利用可能です。

このタグでメッセージ履歴ウィンドウを表示している間もシナリオは進行するので、進行処理を止めておきたい場合は [waitclick] 等を使って下さい。

hidehistorywindow

メッセージ履歴を非表示

メッセージ履歴ウィンドウを非表示にします。 ただし、「almight.config.js」で「history.html」をプラグインとして読み込んでいる場合のみ利用可能です。

showloadwindow

ロード画面を表示

サイドバーで「ロード」を選択すると表示されるロード画面のウィンドウを、このタグで表示することができます。 ただし、「almight.config.js」で「load.html」をプラグインとして読み込んでいる場合のみ利用可能です。

このタグでロード画面のウィンドウを表示している間もシナリオは進行するので、進行処理を止めておきたい場合は [waitclick] 等を使って下さい。

hideloadwindow

ロード画面を非表示

ロード画面のウィンドウを非表示にします。 ただし、「almight.config.js」で「load.html」をプラグインとして読み込んでいる場合のみ利用可能です。

showsavewindow

セーブ画面を表示

サイドバーで「セーブ」を選択すると表示されるセーブ画面のウィンドウを、このタグで表示することができます。 ただし、「almight.config.js」で「save.html」をプラグインとして読み込んでいる場合のみ利用可能です。

このタグでセーブ画面のウィンドウを表示している間もシナリオは進行するので、進行処理を止めておきたい場合は [waitclick] 等を使って下さい。

hidesavewindow

セーブ画面を非表示

セーブ画面のウィンドウを非表示にします。 ただし、「almight.config.js」で「save.html」をプラグインとして読み込んでいる場合のみ利用可能です。

showsettingwindow

環境設定画面を表示

サイドバーで「環境設定」を選択すると表示される環境設定画面のウィンドウを、このタグで表示することができます。 ただし、「almight.config.js」で「setting.html」をプラグインとして読み込んでいる場合のみ利用可能です。

このタグで環境設定画面のウィンドウを表示している間もシナリオは進行するので、進行処理を止めておきたい場合は [waitclick] 等を使って下さい。

hidesettingwindow

環境設定画面を非表示

環境設定画面のウィンドウを非表示にします。 ただし、「almight.config.js」で「setting.html」をプラグインとして読み込んでいる場合のみ利用可能です。

showtitle

タイトル画面を表示

属性名 必須 デフォルト 説明
storage NO string "first.ks" 呼び出したいファイル名を指定します
target NO string "*newgame" 呼び出したいラベル名を指定します
time NO number 1000 タイトル画面をフェードインさせる時間をミリ秒で指定します

タイトル画面のウィンドウを表示します。 ただし、「almight.config.js」で「title.html」をプラグインとして読み込んでいる場合のみ利用可能です。

このタグでタイトル画面のウィンドウを表示している間もシナリオは進行するので、進行処理を止めておきたい場合は [s] を使って下さい。

hidetitle

タイトル画面を非表示

属性名 必須 デフォルト 説明
time NO number 1000 タイトル画面をフェードアウトさせる時間をミリ秒で指定します

タイトル画面のウィンドウを非表示にします。 ただし、「almight.config.js」で「title.html」をプラグインとして読み込んでいる場合のみ利用可能です。

マクロ操作

macro

マクロの記録開始

属性名 必須 説明
name YES string 記録したいマクロ名
alias NO string マクロ名のエイリアス(別名)

[macro][endmacro] の間を、マクロとして記録します。

マクロ内のタグの属性値には % を頭につけた値を指定できます。 マクロに渡された属性名を指定しておくと、マクロに渡された属性の値をその属性の値とすることができます。

// newmacro という名前のマクロを作成し、エイリアス(別名)に font_color と指定しておく。
[macro name="newmacro" alias="font_color"]
    [font color="%type"]マクロを実行しました[resetfont]
[endmacro]

// 赤い文字で「マクロを実行しました」と表示される
[newmacro type="#ff0000"]

// font_color と書いても newmacro が実行される。
[font_color]

また、その値のあとに | を書いて省略値を指定することもできます。

[macro name="newmacro"]
    [font color="%type|#0000ff"]マクロを実行しました[resetfont]
[endmacro]

// 青い文字で「マクロを実行しました」と表示される
[newmacro]

endmacro

マクロの記録終了

[macro] で記録中のマクロを記録終了します。

erasemacro

記録したマクロの削除

属性名 必須 説明
name YES string 削除したいマクロ名

記録されているマクロを削除します。

// newmacroというマクロを削除します
[erasemacro name="newmacro"]

メッセージ操作

ch

文字の描画

属性名 必須 説明
text YES string 描画する文字

カレントメッセージレイヤーに文字を描画します。

// 「これはテキストです」と表示されます
これは[ch text="テキスト"]です。

このタグを使って文字を描画した場合はアニメーションが実行されません。ですが通常、文字をアニメーションを実行させずに表示したい場合は [nowait] を利用してください 。

Almightでは、デフォルトの文字は1文字づつ分解されて [ch] を通して描画されます。

er

カレントメッセージレイヤーのクリア

カレントメッセージレイヤーをクリアし、文字を消去します。

[font][style] で指定したスタイルは、全て標準状態に戻ります。 [position][layopt] で指定したスタイルは、そのまま引き継がれます。

なお、このタグを実行後も、カレントメッセージレイヤーは同じです。

cm

全てのメッセージレイヤーのクリア

全てのメッセージレイヤーをクリアし、文字を消去します。

[font][style] で指定したスタイルは、全て標準状態に戻ります。 [position][layopt] で指定したスタイルは、そのまま引き継がれます。

なお、このタグを実行後も、カレントメッセージレイヤーは同じです。

ct

全てのメッセージレイヤーのリセット

全てのメッセージレイヤーをリセットし、文字を消去します。 また、カレントメッセージレイヤーを 表(fore)のmessage0 に戻します。

[font][style] で指定したスタイルは、全て標準状態に戻ります。 [position][layopt] で指定したスタイルは、そのまま引き継がれます。

current

カレントメッセージレイヤーを指定

属性名 必須 デフォルト 説明
layer NO "message0", "message1", "message2"... currentLayer 操作対象にするメッセージレイヤー。省略すると、カレントメッセージレイヤーが指定されます
page NO "fore", "back" "fore" 表(fore)と裏(back)のどちらを操作対象にするか指定します

タグによる操作対象とするメッセージレイヤー(カレントメッセージレイヤー)を指定します。

文字の描画や [font] による文字属性の設定など、全てここで指定したカレントメッセージレイヤーが対象となります。

// メッセージレイヤー0の表ページが指定されます
[current layer="message0" page="fore"]

font

フォントを設定

属性名 必須 デフォルト 説明
size NO number または "default" "default" フォントサイズをpx単位で指定
face NO string または "default" "default" フォント名を指定。CSSのfont-familyに準拠
color NO string または "default" "default" 文字色を[0xRRGGBB]かCSSのcolorに指定出来る形式で指定
shadow NO boolean または "default" "default" 文字を影付きにするかどうか
shadowcolor NO string または "default" "default" 文字を影付きにする場合、色を[0xRRGGBB]かCSSのcolorに指定出来る形式で指定
shadowpos NO string または "default" "default" 文字を影付きにする場合に、影の横位置、縦位置、ぼかしをpx単位で指定
bold NO boolean または "default" "default" 太字にするかどうか

フォントを設定します。

いずれもの属性も、省略すると以前の状態が引き継がれます。 また、defaultを設定するとデフォルトフォントの状態に戻ります。

このタグで指定した属性は、 [resetfont][ct][cm][er] が実行されると、デフォルトフォントに戻ります。

// 「赤色」という文字だけ文字色が赤色になります。
次の文字を[font color="#ff0000"]赤色[resetfont]で表示します。

// 「影付きで表示します。」の文字に、横1px 縦2px ぼかし5px の白色の影がつきます。
次の文字を[font shadow=true shadowcolor="#ffffff" shadowpos="1px 2px 5px"]影付きで表示します。

style

行スタイルを設定

属性名 必須 デフォルト 説明
align NO "left","right","center","justify" または "default" "default" 行の文字揃えを指定できます。それぞれ、left(左寄せ) / right(右寄せ) / center(中央揃え) / justify(均等割付 となります。
lineheight NO number または "default" "default" 行間をpx単位で指定
pitch NO number または "default" "default" 文字間のオフセットをpx単位で指定

行スタイルを設定します。

いずれもの属性も、省略すると以前の状態が引き継がれます。 また、defaultを設定するとデフォルト行スタイルの状態に戻ります。

このタグで指定した属性は、 [resetfont][ct] が実行されると、デフォルト行スタイルに戻ります。

// 「中央位置」という文字だけセンタリングされて表示されます
次の文字だけ[r]
[style align="center"]中央位置[r][resetstyle]
に表示されます[p]

deffont

デフォルトフォントを設定

属性名 必須 説明
size NO number フォントサイズをpx単位で指定
face NO string フォント名を指定。CSSのfont-familyに準拠
color NO string 文字色を[0xRRGGBB]かCSSのcolorに指定出来る形式で指定
shadow NO boolean 文字を影付きにするかどうか
shadowcolor NO string 文字を影付きにする場合、色を[0xRRGGBB]かCSSのcolorに指定出来る形式で指定
shadowpos NO string 文字を影付きにする場合に、影の横位置、縦位置、ぼかしをpx単位で指定
bold NO boolean 太字にするかどうか

カレントメッセージレイヤーのカレントページに対する、デフォルトのフォントを設定します。

文字の一部分のフォントを変えたい場合は、 [font] を使用してください。 また、このタグでデフォルトのフォントを設定したあと、すぐにゲーム中に反映させるには [resetfont] を使用してください。

属性を省略すると設定は変更されません。

// 「文字色を赤文字にします。」という部分が赤色になります。
[deffont color="#ff0000"]次の文字から[resetfont]文字色を赤文字にします。

// 「影付きで表示します。」の文字に、横1px 縦2px ぼかし5px の白色の影がつきます。
[deffont shadow=true shadowcolor="#ffffff" shadowpos="1px 2px 5px"]次の文字を[resetfont]影付きで表示します。

defstyle

デフォルト行スタイルを設定

属性名 必須 説明
align NO "left","right","center","justify" 行の文字揃えを指定できます。それぞれ、left(左寄せ) / right(右寄せ) / center(中央揃え) / justify(均等割付)、となります。
lineheight NO number 行間をpx単位で指定
pitch NO number 文字間のオフセットをpx単位で指定

カレントメッセージレイヤーのカレントページに対する、デフォルトの行スタイルを設定します。

文字の一部分の行スタイルを変えたい場合は、 [style] を使用してください。 また、このタグでデフォルトの行スタイルを設定したあと、すぐにゲーム中に反映させるには [resetstyle] を使用してください。

属性を省略すると設定は変更されません。

// 「中央位置に表示します。」という部分から中央位置に表示されます。
[defstyle align="center"]次の文字から[r][resetstyle]中央位置に表示します。

nowait

文字表示の速度をノーウェイトに設定

文字表示のアニメーション速度をノーウェイトに設定します。

終了するには [endnowait] を使用します

endnowait

文字表示ノーウェイトを解除

[nowait] で設定されていた、文字表示のノーウェイトを解除します。

delay

文字表示の速度を設定

属性名 必須 説明
speed YES number または"nowait","user" 文字のアニメーション速度をミリ秒で指定。"nowait"を指定すると文字が即時に表示されるようになります。"user"を指定した場合は環境設定画面でユーザーが設定した文字速度になります。

文字表示のアニメーション速度を設定します。 なお、速度は全てのメッセージレイヤーで同じです。

文字表示のアニメーションをなしにするには、 [nowait] を使用してください。

// 文字を500ミリ秒で表示します。
[delay speed=500]文字を0.5秒で表示します。

// 文字を即時に表示します。
[delay speed="nowait"]文字を即時に表示します。

// 文字をユーザーが設定した速度で表示します。
[delay speed="user"]ユーザーが指定した速度で表示します。

graph

画像を文字中に表示

属性名 必須 説明
storage YES string 画像のファイルパス

テキスト描画位置に画像をインラインで表示します。

フォントに含まれていないような特殊な記号や外字を画像にして、それを表示させるような用途に利用します。

// 「こんにちは」の後にハートマークの画像が表示されます
こんにちは[graph storage="heart.png"]

l

行末クリック待ち

行末記号を表示してクリックを待ちます。

p

改ページクリック待ち

改ページ記号を表示してクリックを待ちます。

r

改行する

改行を挿入します。

resetfont

フォントをデフォルトに戻す

[font] で指定した文字の属性をデフォルトフォントに戻します。

resetstyle

行スタイルをデフォルトに戻す

[style] で指定した行のスタイルをデフォルト行スタイルに戻します。

locate

文字表示位置の設定

属性名 必須 デフォルト 説明
x NO number 0 横方向の位置をpx単位で指定
y NO number 0 縦方向の位置をpx単位で指定

文字を描画する位置を設定します。

メッセージレイヤーのマージンの値(marginl + margint)が実際には加算されるので注意して下さい。

// x座標200px y座標400px の位置から「テキストです。」という文字を表示します。
[locate x=200 y=400]テキストです。

position

メッセージレイヤーの属性を設定

属性名 必須 デフォルト 説明
layer NO "message0", "message1", "message2"... currentLayer 操作対象にするメッセージレイヤー。省略すると、カレントメッセージレイヤーが指定されます
page NO "fore", "back" currentPage 表(fore)と裏(back)のどちらを操作対象にするか指定します。省略すると、カレントページが指定されます
left NO number レイヤーの左端位置をpx単位で指定
top NO number レイヤーの上端位置をpx単位で指定
width NO number レイヤーの横幅をpx単位で指定
height NO number レイヤーの縦幅をpx単位で指定
marginl NO number 左からのマージン(余白)をpx単位で指定
margint NO number 上からのマージン(余白)をpx単位で指定
marginr NO number 右からのマージン(余白)をpx単位で指定
marginb NO number 下からのマージン(余白)をpx単位で指定
visible NO boolean レイヤーの可視状態を指定。trueで可視になり、falseで不可視になります
frame NO string レイヤーの背景に指定する画像のファイルパスを指定。使わないときは""を指定すると、color, opacity属性で指定した単色が表示されます
color NO string レイヤーの背景に指定する色を[0xRRGGBB]かCSSのcolorに指定出来る形式で指定(frame属性が""のときに有効)
opacity NO number レイヤーの背景に指定した色の不透明度を0〜255の範囲で指定(frame属性が""のときに有効)。 [layopt] で指定するopacity属性はレイヤーそのものの不透明度を設定するものですが、こちらは背景色の不透明度を設定します

メッセージレイヤーの属性を設定します。

属性を省略すると設定は変更されません。

// メッセージレイヤー0の背景にメッセージウィンドウ画像を表示させます。画像の中に文字が収まるように幅と高さとマージンを指定しています。
[position layer="message0" page="fore" left=0 top=550 width=1024 height=218 marginl=20 margint=10 marginr=20 marginb=10 visible=true frame="msg_win.png"]

メッセージ履歴操作

hact

メッセージ履歴アクションを設定

属性名 必須 説明
exp YES string クリックされたときに実行するJavaScript式

[hact] から [endhact] までの囲まれた部分は、メッセージ履歴上でクリックできるようになります。 クリックした時に、exp属性で指定されていたJavaScriptが実行されます。

// メッセージ履歴に、クリックするとボイスを再生するアクションを追加
[macro name="voice"]
[hact exp="&hactVoice()"]
[playse storage="%file"]
[endmacro]

endhact

メッセージ履歴アクションの終了

[hact] で設定したメッセージ履歴アクションの範囲指定を終了します。

hr

メッセージ履歴の改行

メッセージ履歴を改行します。

history

メッセージ履歴の設定

属性名 必須 説明
output NO boolean メッセージ履歴にテキストを出力するか指定する
enabled NO boolean メッセージ履歴を表示可能か指定する

メッセージ履歴の設定を行います。

属性を省略すると設定は変更されません。

// メッセージ履歴にテキストを出力しないように設定します
[history output=false]この文字はメッセージ履歴に表示されません

// メッセージ履歴を表示しないようにします
[history enabled=false]

clearhistory

メッセージ履歴のクリア

メッセージ履歴をクリアします。タイトル画面に戻った時など、本編シナリオが終了したところで使用して下さい。

ラベル・シナリオ操作

choices

選択肢の表示

属性名 必須 デフォルト 説明
text[1〜9] YES string それぞれの選択肢に表示する文字列
storage[1〜9] NO string currentScenario それぞれの選択肢が選択されたとき、呼び出したいシナリオファイル名。省略すると現在のシナリオファイルとみなします
target[1〜9] NO string currentScenarioTop それぞれの選択肢が選択されたとき、呼び出したいラベル名。省略するとシナリオファイルの先頭とみなします
exp[1〜9] NO string それぞれの選択肢が選択されたとき、実行されるJS式
cond[1〜9] NO string JS式を評価し、値がfalseだったときは、その選択肢が表示されなくなります

選択肢を表示します。

text1, text2, text3... と属性を追加して、複数の選択肢を表示することができます。 既に選択肢が表示されている状態であればエラーを返します。

// 選択肢を2つ表示。
// りんごが選択された場合は *apple というラベルにジャンプし、ゲーム変数 f.apple には true が代入されます。
[choices text1="りんご" target1="*apple" exp1="f.apple = true" text2="いちご" target2="*strawberry" exp2="f.strawberry = true"]

どれかの選択肢を選ぶと、選択肢は非表示になります。targetとstorageは省略可能ですが、textは省略できません。

button

グラフィカルボタンの表示

属性名 必須 デフォルト 説明
graphic YES string ボタンにする画像ファイル
storage NO string currentScenario ボタンが選択されたとき、呼び出したいシナリオファイル名。省略すると現在のシナリオファイルとみなします
target NO string currentScenarioTop 呼び出したいラベル名。省略するとシナリオファイルの先頭とみなします
exp NO string それぞれの選択肢が選択されたとき、実行されるJS式
onenter NO string ボタンの中にカーソルが入った時に実行されるJS式
onleave NO string ボタンからカーソルが外に出た時に実行されるJS式
clickse NO string ボタンをクリックした時に再生する効果音のファイル
clicksebuf NO number ボタンをクリックした時に再生する効果音のバッファ番号
enterse NO string ボタンの中にカーソルが入った時に再生する効果音のファイル
entersebuf NO number ボタンの中にカーソルが入った時に再生する効果音のバッファ番号
leavese NO string ボタンからカーソルが外に出た時に再生する効果音のファイル
leavesebuf NO number ボタンからカーソルが外に出た時に再生する効果音のバッファ番号

現在のメッセージレイヤー上に、画像リンクを作成します。

ボタンの作成される位置は [locate] タグで指定した位置が左上の座標となります。 また、graphic属性で指定する画像ファイルは「通常の状態」「ボタンを押下した状態」「ボタンの上にカーソルがある状態」の順で、同じサイズの画像を横並びに並べた画像となります。

このタグを使う場合はなるべく [s] タグで選択待ち状態にして、ジャンプ先で [er] を実行してボタンを消去します。

// x座標200px y座標500px の位置にりんごのボタンを表示させます。
// ボタンが押された場合は *apple ラベルのジャンプし、ゲーム変数 f.apple に true を代入します。
[locate x=200 y=500]
[button graphic="apple_btn.png" target="*apple" exp="f.apple = true"]
[s]

call

サブルーチンの呼び出し

属性名 必須 デフォルト 説明
storage NO string currentScenario 呼び出したいシナリオファイル名。省略すると現在のシナリオファイルとみなします
target NO string currentScenarioTop 呼び出したいラベル名。省略するとシナリオファイルの先頭とみなします

サブルーチンを呼び出します。

サブルーチンを呼び出した場合は、必ず [return] で呼び出した元の場所か、指定した場所に戻す必要があります。

// 「callタグでここにジャンプします。」、「returnタグでここにもどってきます。」の順番でテキストが表示されます。
[call target="*call_test"]
returnタグでここにもどってきます。

*call_test
callタグでここにジャンプします。
[return]

return

サブルーチンから戻る

属性名 必須 デフォルト 説明
storage NO string currentScenario 呼び出したいシナリオファイル名。省略すると現在のシナリオファイルとみなします
target NO string currentScenarioTop 呼び出したいラベル名。省略するとシナリオファイルの先頭とみなします

storage属性とtarget属性の両方を省略すると、サブルーチンを呼び出した [call] の場所に戻ります。

サブルーチンを呼び出した場合は、必ず [return] で呼び出した元の場所か、指定した場所に戻す必要があります。 storage属性とtarget属性の両方を省略すると、サブルーチンを呼び出した [call] の場所に戻ります。

// 「移動順 1番」「移動順 2番」「移動順 3番」「移動順 4番」の順にテキストが表示されます。
[call target="*call_test01"]
移動順 2番

[call target="*call_test02"]

*call_test01
移動順 1番
[return]

*call_test02
移動順 3番
[return target="*call_test03"]

*call_test03
移動順 4番

link

ハイパーリンクを設定

属性名 必須 デフォルト 説明
storage NO string currentScenario 呼び出したいシナリオファイル名。省略すると現在のシナリオファイルとみなします
target NO string currentScenarioTop 呼び出したいラベル名。省略するとシナリオファイルの先頭とみなします
exp NO string クリックされたときに実行するJavaScript式

[link][endlink] で囲われた文字を、ハイパーリンクとします。

exp属性を指定すると、クリックされた時にJavaScriptを実行することが出来ます。

このタグを使う場合はなるべく [s] タグで選択待ち状態にして、ジャンプ先で [er] を実行してボタンを消去します。

// リンクを押下すると *apple ラベルにジャンプし、ゲーム変数 f.apple に true が代入されます
[link target="*apple" exp="f.apple = true"]この文字がリンクになります[endlink]

endlink

ハイパーリンクの終了

[link] で設定したハイパーリンクの範囲指定を終了します。

jump

シナリオのジャンプ

属性名 必須 デフォルト 説明
storage NO string currentScenario 呼び出したいシナリオファイル名。省略すると現在のシナリオファイルとみなします
target NO string currentScenarioTop 呼び出したいラベル名。省略するとシナリオファイルの先頭とみなします

指定された場所にシナリオをジャンプさせます。

// first.ks というファイルの *start というラベルにジャンプします
[jump storage="first.ks" target="*start"]

レイヤー操作

backlay

表レイヤーを裏レイヤーにコピー

属性名 必須 デフォルト 説明
layer NO "base", number, "message", "message0", "message1"… allLayer "base"は背景レイヤー、0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤー 、省略すると全てのレイヤーが対象となります

指定したレイヤー、もしくは全ての表レイヤーを裏レイヤーにコピーします

[trans] は裏レイヤーを表レイヤーに書き換えてトランジションするため、 [trans] を使う前には [backlay] で表レイヤーを裏レイヤーにコピーして初期化する必要があります。

// 以下のように書くと全てのレイヤーを裏レイヤーにコピーしてから背景画像だけ変更しているので、トランジションする際に背景のみが切り替わります。
[backlay]
[image storage="bg.jpg" layer="base" page="back" visible=true]
[trans method="crossfade" time=500]
[wt]

// 以下のように書くと、前景レイヤーに複数画像がある場合、レイヤー1だけ裏レイヤーにコピーするので、レイヤー1以外のレイヤーがトランジションで切り替わります。
[freeimage all=true page="back"]
[backlay layer=1]
[trans method="crossfade" time=500]
[wt canskip=true]

forelay

裏レイヤーを表レイヤーにコピー

属性名 必須 デフォルト 説明
layer NO "base", number, "message", "message0", "message1"… allLayer "base"は背景レイヤー、0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤー 、省略すると全てのレイヤーが対象となります

指定したレイヤー、もしくは全ての裏レイヤーを表レイヤーにコピーします

// 全ての裏レイヤーを表レイヤーにコピーします
[forelay]

// レイヤー0の裏レイヤーのみを表レイヤーにコピーします
[forelay layer=0]

copylay

レイヤーのコピー

属性名 必須 デフォルト 説明
srclayer YES "base", number, "message", "message0", "message1"… コピー元のレイヤーを指定します。
destlayer YES "base", number, "message", "message0", "message1"… コピー先のレイヤーを指定します。
srcpage NO "fore","back" "fore" コピー元のページを指定します。
destpage NO "fore","back" "fore" コピー先のページを指定します。

指定したレイヤーを指定されたレイヤーにコピーします。 コピーできるレイヤーは同属のレイヤーにかぎります。 背景レイヤーは背景レイヤーに、前景レイヤーは前景レイヤーに、メッセージレイヤーはメッセージレイヤーに、コピーするように指定して下さい。

// 前景レイヤー0を前景レイヤー1にコピーします
[copylay srclayer=0 destlayer=1]

// メッセージレイヤー0の表ページを、メッセージレイヤー1の裏ページにコピーします
[copylay srclayer="message0" destlayer="message1" srcpage="fore" destpage="back"]

fillrect

単色矩形の描画

属性名 必須 デフォルト 説明
layer YES "base", number "base"は背景レイヤー、0以上の整数は前景レイヤー
page NO "fore","back" "fore" 表(fore)と裏(back)のどちらを操作対象にするか指定
top NO number 0 描画上端位置をpx単位で指定
left NO number 0 描画左端位置をpx単位で指定
width NO number 100 横幅をpx単位で指定
height NO number 100 縦幅をpx単位で指定
color NO String "0xffffff" 塗りつぶす色を[0xRRGGBB]かCSSのcolorに指定出来る形式で指定
opacity NO number 255 不透明度を0〜255の範囲で指定

指定したレイヤーに、指定した色・幅・高さの矩形を描画します。

// leftが0px、topが0pxの位置に、幅と高さが100pxの白い矩形を描画します。
[fillrect layer=0 page="fore"]
// leftが0px、topが100pxの位置に、幅50px、高さ100pxの青い矩形を描画します。
[fillrect layer=0 top=100 width=50 color="0x0000ff"]

freeimage

レイヤー画像をクリア

属性名 必須 デフォルト 説明
layer YES "base", number "base"は背景レイヤー、0以上の整数は前景レイヤーが対象となります
page NO "fore", "back" "fore" 表(fore)と裏(back)のどちらを操作対象にするか指定します
all NO boolean trueにすると全ての前景レイヤーが対象になります

レイヤーに読み込まれた画像をクリアします。

// レイヤー0の表レイヤーのみクリアします
[freeimage layer=0 page="fore"]

// 全ての前景レイヤーの裏レイヤーをクリアします
[freeimage all=true page="back"]

image

画像を読み込み

属性名 必須 デフォルト 説明
storage YES string 画像のファイルパス
layer YES "base", number "base"は背景レイヤー、0以上の整数は前景レイヤーが対象となります
page NO "fore", "back" "fore" 表(fore)と裏(back)のどちらを操作対象にするか指定します
visible NO boolean レイヤーの可視状態を指定。trueで可視になり、falseで不可視になります
left NO number レイヤーの左端位置をpx単位で指定
top NO number レイヤーの上端位置をpx単位で指定
pos NO "left","left_center","center","right_center","right" 前景レイヤーの位置を、左寄り、中央左寄り、中央、中央右寄り、右寄りの位置に指定します(値には略称の"l","lc","c","rc","r"を指定することも可能です)。この属性を指定した場合はleft属性とtop属性の値は無視されます。
opacity NO number レイヤーの不透明度を0〜255の範囲で指定

指定されたレイヤーに画像を読み込んで表示します。

// 背景レイヤーの表レイヤーに画像を読み込みます
[image storage="bg.jpg" layer="base" visible=true]

// 前景レイヤー1の表レイヤー、左から200px、上から100px、の位置にりんご画像を読み込みます
[image storage="apple.png" layer=1 visible=true left=200 top=100]

// 前景レイヤー2の中央位置にいちご画像を読み込みます
[image storage="strawberry.png" layer=2 visible=true pos="center"]

pimage

画像の追加読み込み

属性名 必須 デフォルト 説明
storage YES string 画像のファイルパス
layer YES "base", number "base"は背景レイヤー、0以上の整数は前景レイヤーが対象となります
page NO "fore", "back" "fore" 表(fore)と裏(back)のどちらを操作対象にするか指定します
dx YES number 追加で読み込む画像の左端X座標をpx単位で指定
dy YES number 追加で読み込む画像の上端Y座標をpx単位で指定
opacity NO number レイヤーの不透明度を0〜255の範囲で指定

指定されたレイヤーに画像を追加読み込んで表示します。

// 背景レイヤーの表レイヤー、x座標200px、Y座標100px、の位置にりんご画像を追加で読み込みます
[pimage storage="apple.png" layer="base" dx=200 dy=100]

layopt

レイヤーの属性を設定

属性名 必須 デフォルト 説明
layer YES number, "message", "message0", "message1"… 0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤーが対象となります
page NO "fore", "back" "fore" 表(fore)と裏(back)のどちらを操作対象にするか指定します。layer属性に"message"を指定した場合、この属性を省略するとカレントメッセージレイヤーのページが選択されます
left NO number レイヤーの左端位置をpx単位で指定
top NO number レイヤーの上端位置をpx単位で指定
visible NO boolean レイヤーの可視状態を指定。trueで可視になり、falseで不可視になります
opacity NO number レイヤーの不透明度を0〜255の範囲で指定。 [position] で指定するopacity属性は背景色の不透明度を設定するものですが、こちらはレイヤーそのものの不透明度を設定します

指定されたレイヤーの属性を設定します。

// レイヤー0にりんご画像を読み込む
[image storage="apple.png" layer=0]
// レイヤー0のりんご画像をx座標100px、y座標200px、の位置に移動させ、不透明度を100にし、半透明にします。
[layopt layer=0 left=100 top=200 visible=true opacity=100]

laycount

レイヤーの枚数を変更

属性名 必須 説明
layers NO number 前景レイヤーの枚数を指定
messages NO number メッセージレイヤーの枚数を指定

メッセージレイヤーや、前景レイヤーの枚数を変更します。

レイヤーの枚数は特にスマートフォンでの動作に大きく関わりがあり、レイヤーの枚数を不用意に増やすとメモリ不足で強制終了する可能性もあります。 そのため、レイヤーは使用する必要最低限の枚数に設定して下さい。

出来るだけconfigファイルで最初にレイヤーの枚数を設定し、このタグで変更することのないように設計するか、 必要なシーンだけレイヤーを増やして使い終わったら減らすようにしてください。

属性を省略すると設定は変更されません。

// レイヤー数を10に増やします
[laycount layers=10]

// メッセージレイヤー数を10に増やします
[laycount messages=10]

trans

トランジションを実行する

属性名 必須 デフォルト 説明
time YES number トランジションする時間をミリ秒で指定
method NO "universal", "crossfade" "crossfade" トランジションタイプを指定します。"universal"は、ルール画像に従ってトランジションを実行します。"crossfade"は、単純なクロスフェードを実行します
rule method="universal"ならYES string ルール画像のファイル名

ステージをトランジションします。

全てのレイヤーの裏レイヤーと表レイヤーが入れ替わり、その時にトランジションが実行されます。

// bg.jpgを1秒のクロスフェードで表示する例
[backlay]
[image storage="bg.jpg" layer=0 page="back"]
[trans time=1000]
[wt]

このタグはトランジションの実行を待たないため、 [wt] で待ってください。

stoptrans

トランジションの実行を中止

[trans] でトランジション中の場合、トランジションの実行を停止します。

即時、トランジション後の状態になります。

// waitclickタグをクリックで進めると、stoptransタグでトランジションが即時終了します。
[backlay]
[image storage="strawberry.png" layer=0 page="back" visible=true]
[trans time=10000]
[waitclick]
[stoptrans]

wt

トランジションの終了を待つ

属性名 必須 デフォルト 説明
canskip NO boolean true trueならスキップ可能、falseならスキップさせない

トランジションの終了を待ちます。

// 以下の場合はクリックでトランジションを即時に終了できます
[backlay]
[image storage="bg.jpg" layer=0 page="back"]
[trans time=1000]
[wt canskip=true]

// 以下の場合はトランジションの終了を待ちます
[backlay]
[image storage="bg.jpg" layer=0 page="back"]
[trans time=1000]
[wt canskip=false]

move

レイヤーの移動アニメーション

属性名 必須 デフォルト 説明
layer YES number, "message", "message0", "message1"… 0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤーが対象となります
page NO "fore", "back" "fore" 表(fore)と裏(back)のどちらを操作対象にするか指定します
time YES number アニメーションする時間をミリ秒で指定
path YES string 移動位置は、x座標、y座標、opacityを3つづつ、カンマで区切って指定します
accel NO -5~5の範囲 0 徐々に加速、徐々に減速、という動きをさせるか指定します。1以上の数を指定すると徐々に加速しながら移動し、-1以下の数字を指定すると徐々に減速しながら移動します。0を指定した場合は一定の速さで移動します。
// 例
[move time=4000 path="(0,240,255) (0,0,255) (0,-240,255) (0,-480,0)" layer=0]
[wm layer=0]

このタグはレイヤーの移動アニメーションの終了を待たずにシナリオを進行します。待つ場合は [wm] を直後に記述してください。 その際、 [wm] には [move] に指定したレイヤーと同様のレイヤーを指定してください。

anim

レイヤーのアニメーション

属性名 必須 デフォルト 説明
layer YES "base", number, "message", "message0", "message1"… "base"は背景レイヤー、0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤーが対象となります
page NO "fore", "back" "fore" 表(fore)と裏(back)のどちらを操作対象にするか指定します
time YES number アニメーションする時間をミリ秒で指定
left NO number 移動先のx座標の位置をpxで指定
top NO number 移動先のy座標の位置をpxで指定
opacity NO number レイヤーの不透明度を0か1で指定。0なら透明に、1なら不透明になります.
rotate NO string 回転する角度を、"90deg"や"360deg"のようにdegで指定。
scale NO numer 拡大・縮小を倍率で指定。2なら2倍の大きさになります。
skewX NO string x軸の傾斜角度を、"10deg"のようにdegで指定。指定した角度に沿ってx軸方向に傾斜変形します。
skewY NO string y軸の傾斜角度を、"10deg"のようにdegで指定。指定した角度に沿ってy軸方向に傾斜変形します。
easing NO string アニメーションの実行スピードのパターンを指定します。"linear", "ease", "in", "out", "in-out", "snap"...等
delay NO number アニメーションが開始するまでの待機時間をミリ秒で指定

easingのパターンを早見表としてまとめているサイトがありますので、そちらを参考にして下さい。

http://easings.net/ja

このタグはレイヤーのアニメーションの終了を待たずにシナリオを進行します。待つ場合は [wm] を直後に記述してください。 その際、 [wm] には [anim] に指定したレイヤーと同様のレイヤーを指定してください。

// animタグを複数連続して書き、最後にanimstartで実行することもできます。
// 以下の場合は30度の位置に回転する動きの後、-30度の位置に回転する動きをし、初期値の0度の位置に回転します。
[anim page="fore" layer=5 rotate="30deg" time=500]
[anim page="fore" layer=5 rotate="-30deg" time=500]
[anim page="fore" layer=5 rotate="0deg" time=500]
[animstart layer=5]
[wm layer=5]

animstart

レイヤーのアニメーションを実行

属性名 必須 デフォルト 説明
layer YES "base", number, "message", "message0", "message1"… "base"は背景レイヤー、0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤーが対象となります
page NO "fore", "back" "fore" 表(fore)と裏(back)のどちらを操作対象にするか指定します

[anim] で指定したアニメーションを実行します。 [anim] に指定したレイヤーと同様のレイヤーを [animstart] に指定してください。

wm

レイヤーの移動アニメーションの終了を待つ

属性名 必須 デフォルト 説明
layer YES "base", number, "message", "message0", "message1"… "base"は背景レイヤー、0以上の整数は前景レイヤー、"message"はカレントメッセージレイヤー、"message0"や"message1"…で任意のメッセージレイヤーが対象となります
canskip NO boolean true trueならスキップ可能、falseならスキップさせない。レイヤーの移動アニメーションの途中で終了待ちをスキップした場合は、即時に移動終了位置に移動します。
// 以下の場合は、クリックで移動アニメーション処理を終了します
[move time=4000 path="(0,240,255) (0,0,255) (0,-240,255) (0,-480,0)" layer=0]
[wm layer=0 canskip=true]

// 以下の場合は移動アニメーション処理の終了を待ちます
[move time=4000 path="(0,240,255) (0,0,255) (0,-240,255) (0,-480,0)" layer=0]
[wm layer=0 canskip=false]

BGM・SE操作

playbgm

BGMを再生

属性名 必須 デフォルト 説明
storage YES string BGMのファイル名
loop NO boolean true BGMをループ再生するか指定します

BGMファイルを再生します。

このタグは音声の再生終了を待たないため、 [wl] で待ってください。

// 音声をループ再生します
[playbgm storage="bgm.ogg" loop=true]

// 音声の再生終了を待ちます
[playbgm storage="bgm.ogg" loop=false]
[wl canskip=false]

// クリックで音声を即時停止します
[playbgm storage="bgm.ogg" loop=false]
[wl canskip=true]

wl

BGMの再生終了を待つ

属性名 必須 デフォルト 説明
canskip NO boolean false trueならスキップ可能、falseならスキップさせない

BGMの再生を最後まで待ちます。

再生時にloopがtrueになっていたときは待たずに続行します。 スキップするとBGMは即時停止します

stopbgm

BGMを停止

再生中のBGMを停止します。

fadeinbgm

BGMのフェードイン再生

属性名 必須 デフォルト 説明
storage YES string BGMのファイル名
time YES number フェードする時間をミリ秒で指定します
loop NO boolean true BGMをループ再生するか指定します

BGMファイルを無音状態からフェードインで再生します。

このタグはフェードの終了を待たないため、 [wb] で待ってください。

// 3秒掛けて音声がフェードインします
[fadeinbgm storage="bgm.ogg" time=3000 loop=true]

// 3秒掛けて音声がフェードインします。フェードインの終了を待ちます。
[fadeinbgm storage="bgm.ogg" time=3000 loop=true]
[wb]

// 3秒掛けて音声がフェードインします。クリックするとフェードインを即時に終了します。
[fadeinbgm storage="bgm.ogg" time=3000 loop=true]
[wb canskip=true]

fadeoutbgm

BGMをフェードアウトして停止

属性名 必須 デフォルト 説明
time YES number フェードする時間をミリ秒で指定します

BGMをフェードアウトして停止します。

このタグはフェードの終了を待たないため、 [wb] で待ってください。

// 再生中のbgmを3秒かけてフェードアウトします。
[fadeoutbgm time=3000]

// 再生中のbgmを3秒掛けてフェードアウトします。フェードアウトの終了を待ちます。
[fadeoutbgm time=3000]
[wb canskip=false]

// 再生中のbgmを3秒掛けてフェードアウトします。クリックすると即時に音声が終了します。
[fadeoutbgm time=3000]
[wb canskip=true]

fadebgm

BGMを指定音量までフェード

属性名 必須 デフォルト 説明
time YES number フェードする時間をミリ秒で指定します
volume YES number BGMの音量を0〜100で指定します

再生中のBGMを指定音量までフェードさせます。

このタグはフェードの終了を待たないため、 [wb] で待ってください。

// bgmを3秒掛けてボリューム50%にします。
[fadebgm time=3000 volume=50]

// bgmを3秒掛けてボリューム0%にします。フェードの終了を待ちます。
[fadebgm time=3000 volume=0]
[wb canskip=false]

// bgmを3秒掛けてボリューム100%にします。クリックすると即時にボリュームが100%になります。
[fadebgm time=3000 volume=100]
[wb canskip=true]

wb

BGMフェードの終了を待つ

属性名 必須 デフォルト 説明
canskip NO boolean false trueならスキップ可能、falseならスキップさせない

BGMのフェードの終了を待ちます。

bgmopt

BGMの音量を設定

属性名 必須 デフォルト 説明
volume NO number BGMの音量を0〜100で指定します。
gvolume NO number BGMの音量を0〜100で指定します。実際の音量は、volumeの値とこの属性を掛け合わせた数字になります。この音量設定はシステム変数に記録され、次回起動時に設定されます。

BGMの音量を設定します。 環境設定画面で、ユーザーが変更できる音量はgvolumeの値です。

// 音量が0%になります。
// 環境設定画面でユーザーが音量を変更しても、実際に再生される音量は0%のままになります。
[bgmopt volume=0 gvolume=100]

// 音量が25%になります。
// もし、ユーザーが環境設定画面で音量を100%にしても、実際に再生される音量は50%までになります。
[bgmopt volume=50 gvolume=50]

playse

SEを再生

属性名 必須 デフォルト 説明
buf NO number 0 効果音のバッファを指定します
storage YES string SEのファイル名
loop NO boolean true SEをループ再生するか指定します

SEファイルを再生します。

このタグは効果音の再生終了を待たないため、 [ws] で待ってください。 その際、 [playse] で指定したbufと同様の数値を [ws] のbufに指定して下さい。

// 効果音をループ再生します。
[playse storage="se01.ogg" buf=0 loop=true]

// 効果音の再生終了を待ちます。
[playse storage="se01.ogg" buf=0 loop=false]
[ws canskip=false]

// 効果音を再生します。クリックでを即時に終了します。
[playse storage="se01.ogg" buf=0 loop=false]
[ws canskip=true]

ws

SEの再生終了を待つ

属性名 必須 デフォルト 説明
buf NO number 0 再生の終了を待つ効果音のバッファを指定します
canskip NO boolean false trueならスキップ可能、falseならスキップさせない

SEの再生終了を待ちます。

stopse

SEを停止

属性名 必須 デフォルト 説明
buf NO number 0 効果音のバッファを指定します

再生中のSEを停止します。

fadeinse

SEのフェードイン再生

属性名 必須 デフォルト 説明
buf NO number 0 効果音のバッファを指定します
storage YES string SEのファイル名
time YES number フェードする時間をミリ秒で指定します
loop NO boolean true SEをループ再生するか指定します

SEファイルを無音状態からフェードインで再生します。

このタグはフェードの終了を待たないため、 [wf] で待ってください。 その際、 [fadeinse] で指定したbufと同様の数値を [wf] のbufに指定して下さい。

// 三秒掛けて効果音をフェードインさせます。フェードの終了を待ちます。
[fadeinse storage="se01.ogg" buf=0 time=3000 loop=false]
[wf buf=0 canskip=false]

// 三秒掛けて効果音をフェードインさせます。クリックでフェードインを即時に終了します。
[fadeinse storage="se01.ogg" buf=0 time=3000 loop=false]
[wf buf=0 canskip=true]

fadeoutse

SEをフェードアウトして停止

属性名 必須 デフォルト 説明
buf NO number 0 効果音のバッファを指定します
time YES number フェードする時間をミリ秒で指定します

SEをフェードアウトして停止します。

このタグはフェードの終了を待たないため、 [wf] で待ってください。 その際、 [fadeoutse] で指定したbufと同様の数値を [wf] のbufに指定して下さい。

// 三秒掛けて効果音がフェードアウトします。フェードの終了を待ちます。
[fadeoutse buf=0 time=3000]
[wf buf=0 canskip=false]

// 三秒掛けて効果音がフェードアウトします。クリックで即時に音声が終了します。
[fadeoutse buf=0 time=3000]
[wf buf=0 cansip=true]

fadese

SEを指定音量までフェード

属性名 必須 デフォルト 説明
buf NO number 0 効果音のバッファを指定します
time YES number フェードする時間をミリ秒で指定します
volume YES number SEの音量を0〜100で指定します

再生中のSEを指定音量までフェードさせます。

このタグはフェードの終了を待たないため、 [wf] を使用してください。 その際、 [fadese] で指定したbufと同様の数値を [wf] のbufに指定して下さい。

// 三秒掛けて再生中の効果音の音量を0%にします。フェードの終了を待ちます。
[fadese buf=0 time=3000 volume=0]
[wf buf=0 cansip=fasle]

// 三秒掛けて効果音の音量を100%にします。クリックで即時にボリュームが100%になります。
[fadese buf=0 time=3000 volume=100]
[wf buf=0 cansip=true]

wf

SEフェードの終了を待つ

属性名 必須 デフォルト 説明
buf NO number 0 効果音のバッファを指定します
canskip NO boolean false trueならスキップ可能、falseならスキップさせない

SEのフェードの終了を待ちます。

seopt

SEの音量を設定

属性名 必須 デフォルト 説明
buf NO number 0 効果音のバッファを指定します
volume NO number SEの音量を0〜100で指定します。
gvolume NO number SEの音量を0〜100で指定します。実際の音量は、volumeの値とこの属性を掛け合わせた数字になります。この音量設定はシステム変数に記録され、次回起動時に設定されます。

SEの音量を設定します。 環境設定画面で、ユーザーが変更できる音量はgvolumeの値です。

// 音量が0%になります。
// 環境設定画面でユーザーが音量を変更しても、実際に再生される音量は0%のままになります。
[seopt volume=0 gvolume=100]

// 音量が25%になります。
// もし、ユーザーが環境設定画面で音量を100%にしても、実際に再生される音量は50%までになります。
[seopt volume=50 gvolume=50]

シナリオ操作

if

if文の開始

属性名 必須 説明
exp YES string JavaScript式

条件によりシナリオを無視する、if文を開始します。

exp属性の式を評価して、falseならばelsifタグ、elseタグ、endifタグのいずれかまでシナリオを無視します。

// 1 == 1 は正しいので
[if exp="1==1"]
ここが表示される
[else]
ここは表示されない
[endif]

else

else文の開始

ifの中身が実行されなかったときに実行される、else文を開始します。

elsif

else if文の開始

属性名 必須 説明
exp YES string JavaScript式

ifの中身が実行されなかったときに条件付きで実行される、else if文を開始します。

//1 == 1 は正しいので
[if exp="1 == 0"]
    ここは表示されない。
[elsif exp="1 == 1"]
    ここが表示される。
[else]
    ここは表示されない。
[endif]

endif

if文の終了

if文を終了します。

ignore

ignore文の開始

属性名 必須 説明
exp YES string JavaScript式

条件によりシナリオを無視する、ignore文を開始します。

exp属性の式を評価して、trueならばendignoreタグまでシナリオを無視します

// 1 == 1 は正しいので
[ignore exp="1 == 1"]
ここは表示されない
[endignore]

endignore

ignore文の終了

ignore文を終了します。

eval

JavaScriptの評価

属性名 必須 説明
exp YES string JavaScript式

exp属性の式を評価します。

関数、コードの実行や、変数に値を代入する際に用います。

// ゲーム変数 f.cg1 に10を代入
[eval exp="f.cg1=10"]

// ゲーム変数 f.calc に10+25の結果を代入
[eval exp="f.calc=10+25"]

iscript

JavaScriptの開始

[iscript] から [endscript] までの間を、JavaScriptのコードとして評価します。

マクロの中で使うことはできません。

// Hello world! というダイアログが表示されます
[iscript]
alert('Hello world!');
[endscript]

endscript

JavaScriptの終了

[iscript] で記述したJavaScriptコードを終了します。

emb

変数をテキストとして表示

属性名 必須 説明
exp YES string JavaScript式

exp属性の式を評価した値をテキストとして表示します。

// f.fruits に「いちご」と代入
[eval exp="f.fruits='いちご'"]

あなたが好きな果物は… 確か[emb exp="f.fruits"]でしたね。

// → あなたが好きな果物は… 確かいちごでしたね。
//   と出力されます。

clearvar

ゲーム変数を全てリセット

ゲーム変数(f)を全てリセットします。

[eval exp="f={}"] と等価です。

デバッグ

trace

コンソールにログを出力

属性名 必須 説明
exp YES string JavaScript式

exp属性の式を評価した値をコンソールにログとして出力します。

// ゲーム変数 f.apple に りんご という文字列を代入する
[eval exp="f.apple = 'りんご'"]
// コンソールに りんご と出力される
[trace exp="f.apple"]

debugger

プログラムの実行をブレーク

デベロッパーツールに搭載されているデバッガーを起動して、 プログラムの動作をブレークします。

プログラミングの知識がある方向けの機能です。